Doubling the pusle count

[malc-c]

The knowledge and experience you guys have amaizes me !

Woke up this morning and checked this thread and found a suggested schematic from Steve and revised code from Darrel ! - Thanks guys.

I'll compile and burn the code to a 12F675 and send it to my mate for testing.. I'll report back on his findings in a couple of days

[keithdoxey]

The knowledge and experience you guys have amaizes me !

Woke up this morning and checked this thread and found a suggested schematic from Steve and revised code from Darrel ! - Thanks guys.

I'll compile and burn the code to a 12F675 and send it to my mate for testing.. I'll report back on his findings in a couple of days

I would just like to point out that in the event of your mate getting caught for speeding, Steve and Darrels contribution towards the speeding fine will be limited to the amount paid for the code and schematic

[Darrel Taylor]

I don't know if I could afford that Keith

I think Steve's circuit will invert the output, so I'll need to reverse the pulse in the program to be able to use that.

And you need an input circuit. I was thinking something like the circuit below might be nice. And, I'll need to make it use the GP0 input to determine what the Idle polarity is.

I smell a Version 3.

I tried something else, then realized it wouldn't work.
What do you think about this one.

Click Image to Enlarge

Click Image to Enlarge

[malc-c]

Keith, I like where you're coming from

Darrel, that looks good. I've already pointed my mate to this forum so he can keep up to speed to see what a stirling effort you guys are doing !

Thanks guys !

[Darrel Taylor]

Well, for whomever will be using it in the end ...

Here's version 3. Hopefully the last one.
I think I covered all the bases.

Added another input. (see schematic above) GPIO.1 that determines if the output is inverted or not. It has a weak Pull-up, so you can just leave it disconnected for use with the NPN transistor.

'****************************************************************
'*  Name    : FREQx2.bas                                        *
'*  Author  : Darrel Taylor                                     *
'*  Date    : 3/2/2007                                          *
'*  Version : 3.0                                               *
'*  Notes   : Doubles the frequency of input pulses,            *
'*          : and maintains the same DutyCycle as the Input.    *
'*          : Range = .1hz to 500 hz  (0-40% max DutyCyle)      *
'*          : Target = PIC12F629/675                            *
'****************************************************************
@  __config _INTRC_OSC_NOCLKOUT & _WDT_OFF & _MCLRE_OFF & _CP_OFF
DEFINE  NO_CLRWDT 1

Clear

SpeedPin   VAR GPIO.2                       ; Input from speed sensor
SpeedX2Pin VAR GPIO.4                       ; Output to Speedometer
IdleState  VAR GPIO.0                       ; State of input when sensor
                                            ;    is not on a "Slot"
Invert     VAR GPIO.1                       ; Inverts output if = 1

OPTION_REG.7 = 0                            ; enable weak Pull-ups
WPU = 3                                     ; weak Pull-up on GP0 and GP1      
;_____________________________________________________________________________

LastState  VAR BIT                          ; Last state the Input changed to
LoopCount  VAR byte                         ; Counts the loops of each pulse
LoopCount1 VAR byte
LoopCount2 VAR byte

PulseWidth  VAR byte  BANK0                 ; Counts the loops of output pulse
PulseWidth1 VAR byte  BANK0
PulseWidth2 VAR byte  BANK0

LastPulseWidth  VAR byte                    ; saved width of last pulse
LastPulseWidth1 VAR byte                    ;    so it can duplicate it
LastPulseWidth2 VAR byte

CycleWidth  VAR byte  BANK0                 ; Counts the loops of output cycle
CycleWidth1 VAR byte  BANK0
CycleWidth2 VAR byte  BANK0

OutPulseCount VAR BIT


CMCON = 7
'ANSEL = 0    ; for 12F675

SpeedX2Pin = IdleState
OUTPUT SpeedX2Pin

Main:
    LoopCount = LoopCount + 1               ; 24-bit counter
    If LoopCount = 0 Then
        LoopCount1 = LoopCount1 + 1         
        if LoopCount1 = 0 then
            LoopCount2 = LoopCount2 + 1
        endif
    endif
    IF SpeedPin <> LastState then           ; If Input State Changed?
        LastState = SpeedPin
        
        if LastState = (IdleState ^ 1) then         ; Start of Input Pulse
            CycleWidth  = LoopCount
            CycleWidth1 = LoopCount1
            CycleWidth2 = LoopCount2
            ASM
                bcf   STATUS,C              ; CycleWidth = LoopCount / 2
                rrf   _CycleWidth2, F       ; Output Cycle is half of Input
                rrf   _CycleWidth1, F
                rrf   _CycleWidth, F
            ENDASM
            LoopCount  = 0                  ; reset LoopCount
            LoopCount1 = 0
            LoopCount2 = 0
        else                                ; End of Input Pulse
            PulseWidth  = LoopCount
            PulseWidth1 = LoopCount1
            PulseWidth2 = LoopCount2
            ASM
                bcf   STATUS,C              ; PulseWidth = PulseWidth / 2
                rrf   _PulseWidth2, F       ; Output Pulse is half of Input
                rrf   _PulseWidth1, F
                rrf   _PulseWidth, F
            ENDASM
            LastPulseWidth = PulseWidth
            LastPulseWidth1 = PulseWidth1
            LastPulseWidth2 = PulseWidth2
            SpeedX2Pin = ((IdleState ^ 1) ^ Invert) ; start First Output Pulse
            OutPulseCount = 0
        endif
    else
        if SpeedX2Pin = ((IdleState ^ 1) ^ Invert) then
            if PulseWidth = 0 then          ; countdown output time (24bit)
                if PulseWidth1 = 0 then
                    if PulseWidth2 = 0 then
                        SpeedX2Pin = (IdleState ^ Invert) ; end of pulse, 
                    else                       ; wait for next transition
                        PulseWidth2 = PulseWidth2 - 1
                        PulseWidth1 = 255
                        PulseWidth  = 255
                    endif
                else
                    PulseWidth1 = PulseWidth1 - 1
                    PulseWidth  = 255
                endif
            else
                PulseWidth = PulseWidth - 1
            endif
        else
          @ NOP                             ; Keep the loop symmetrical
          @ NOP
          @ NOP
          @ NOP
          @ NOP
          @ NOP
        endif
        
        if OutPulseCount = 0 then
            if CycleWidth = 0 then          ; countdown to Midpoint of cycle
                if CycleWidth1 = 0 then
                    if CycleWidth2 = 0 then
                        SpeedX2Pin = ((IdleState ^ 1) ^ Invert) ; Start second pulse
                        OutPulseCount = 1
                        PulseWidth  = LastPulseWidth
                        PulseWidth1 = LastPulseWidth1
                        PulseWidth2 = LastPulseWidth2
                    else
                        CycleWidth2 = CycleWidth2 - 1
                        CycleWidth1 = 255
                        CycleWidth  = 255
                    endif
                else
                    CycleWidth1 = CycleWidth1 - 1
                    CycleWidth  = 255
                endif
            else
                CycleWidth = CycleWidth - 1
            endif
        else
          @ NOP                             ; Keep the loop symmetrical
          @ NOP
          @ NOP
          @ NOP
          @ NOP
        endif
    endif
goto Main
end

You come up with some fun projects Malcolm. Trains, Automobiles, All we need are planes, and we're set.
<br>

[Acetronics2]

Hi, Darrel

You really want something about planes ....???

I must have a project somewhere for you ... one minute please !

Alain

[malc-c]

I've just received an e-mail from my mate, thought you guys might like to know that he passes on his thanks

Malc...really looks like I've given you guys something to think about with this one. Thank them for their efforts will you and just for the record the car is a 1995 Vauxhall Corsa 1.2 injection...LS

I've programmed the PIC with Darrels code and will build the circuit over the weekend as he doesn't have them to hand

Thanks guys for your help, hopefully it will be positive news when he receives it and fits it to his wifes car