For me the link is OK.

Here it is:

;================================================= ==============================
;******************** xmit some bytes from buffer to PORTB pins6,7 *************
;================================================= ==============================
Send_Coins_1: movlw Puhver
movwf FSR
movf INDF,W ; read timeout value sent by host
movwf temp
movlw 0xFF
movwf T2CON
send_c_0: clrf TMR2
bcf PIR1,TMR2IF
send_c_1: btfss Nupp ; are we allowed to transmit wiegand ?
goto send_c_2 ; yep!
btfss PIR1,TMR2IF ; no, wait until allowed or timeout
goto send_c_1
decfsz temp
goto send_c_0
bcf PIR1,TMR2IF
bcf T2CON,TMR2ON
goto send_c_fail ; taimaut: ****ing off...
send_c_2: bsf pank
bcf TRISB,6 ; permission granted, switch port pins to outputs
bcf TRISB,7
bcf pank
bsf Dat0B ; pins also, not only direction
bsf Dat1B
call taimer ; take a break
incf FSR,F
movf INDF,W
movwf count ; read nr. of bytes to be transmitted
send_c_3: incf FSR,F
movf INDF,W
movwf tomp1
call xmit_wieg ; read byte form "Puhver" and xmit
decfsz count
goto send_c_3 ; until bored
bsf pank
bsf TRISB,6 ; Wiegand port B as input again
bsf TRISB,7
bcf pank
bsf Dat0B
bsf Dat1B
send_c_fail: movlw HIGH main_15
movwf PCLATH
goto main_15 ; return to housekeeping tasks, restore PCLATH
;================================================= ==============================
; ******************** xmiting junk in wiegand format ************
;================================================= ==============================
xmit_wieg: movlw .8 ; 8 bits/byte
movwf tomp
xmit_wieg_1: rlf tomp1,F
btfss CARRY ; form impulse to which pin ?
goto xmit_wieg_2
bcf Dat1B
goto xmit_wieg_3
xmit_wieg_2: bcf Dat0B
xmit_wieg_3: call taimer50uS ; output LOW for about 50uS
call taimer50uS
bsf Dat0B ; lend of pulse, outputs HIGH
bsf Dat1B
call taimer3mS ; 3 mS pause
decfsz tomp ; repeat it 8x
goto xmit_wieg_1
return
taimer3mS: movlw 0x0F
movwf T2CON
clrf TMR2
bcf PIR1,TMR2IF
goto taimer_1
taimer50uS: movlw 0x04
movwf T2CON
movlw 0x82
movwf TMR2
bcf PIR1,TMR2IF
goto taimer_1
taimer: clrf TMR2
movlw 0xFF
movwf T2CON
bcf PIR1,TMR2IF
taimer_1: btfss PIR1,TMR2IF
goto taimer_1
bcf PIR1,TMR2IF
bcf T2CON,TMR2ON
return