Single button function

**Acetronics2** · - 15th January 2008, 13:43

Hi, Konrad

I used such a "multi role" button simply by using the BUTTON Command in a loop...

the example is here,

Code:

'*****************************************************************************
'Servotest 84 D'après Elektor
'*****************************************************************************
'
'16F84A à 20 Mhz

' Barregraph 7 leds sur PortB
' résolution variable 2-6-20 µS
' Mémorisation réglage " moyen"

@  __config _HS_OSC & _WDT_ON & _CP_ON

DEFINE OSC 20 ' 
DEFINE BUTTON_PAUSE 18

Signal	var PortA.0
Writeok	var PortA.1 ' Indicateur mode : 0 = manuel 1 = Cycle
Up 		var PortA.2	' Rotation à Droite
Down 	var PortA.3 ' Rotation à gauche
Prog 	var PortA.4 ' Bouton mémorisation

pos 	var Word
posn 	var Word

compte	var Byte
dir 	var Byte
delay	var Byte
N		var Byte

PORTA 	= 0
PORTB 	= %00001000 'PortB.7 libre, Led centrale allumée.

TRISA 	= %00011100
TRISB 	= %00000000


READ 1, Posn.HighByte
READ 2, Posn.LowByte

IF posn = $FFFF OR posn < 750 OR posn > 2250 THEN posn = 1500
pos = posn

'*****************************************************************************
mainloop:

Writeok = 0

delay = 0

button Up, 		0, 255, 0, delay, 1, upbutton
button Down, 	0, 255, 0, delay, 1, dwnbutton
button Prog, 	0, 255, 0, delay, 1, Program

Gosub Outsig
PAUSE 18
compte = 0

Goto Mainloop


'*****************************************************************************
upbutton:

IF Down = 0 THEN 

	Pos = posn
	Goto Jump1
	
Endif

	Compte = compte + 1
	
	Select Case Compte
	
		Case 255
			Compte = Compte-1
			N = 10
			
		Case is > 50
			N = 10
				
		Case is > 15 
		 	N = 3
		 	
		Case else
			N = 1
			
	End Select
	
   	pos = pos + 2*N
   
   	if pos > 2250 then  pos = 2250
  
Jump1:

For delay = 1 to 9	

	Gosub Outsig
	Pause 18

Next delay

	Gosub Outsig

Goto mainloop


'*****************************************************************************
dwnbutton:

IF Up = 0 THEN 

	Pos = posn
	Goto Jump2
	
Endif

	Compte = compte + 1
	
	Select Case Compte
	
		Case 255
			Compte = Compte - 1
			N = 10
			
		Case is > 50
			N = 10
			
		Case is > 10 
		 	N = 3
		 			
		Case else
			N = 1
			
	End Select
	
   	pos = pos - 2*N
   
   	if pos < 750 then pos = 750
   	 
Jump2:
	
For delay = 1 to 9	

	Gosub Outsig
	Pause 18

Next delay

	Gosub Outsig

 Goto mainloop
 

'*****************************************************************************
Program:

Compte = 0

Test: 

IF Prog = 0 Then 
	
	compte = compte + 1
	Gosub Outsig
	Pause 18
	
	IF Compte > 250 THEN Compte = 250: Goto Test
	IF Compte >= 80 THEN WriteoK = Compte .4 : Goto Test
	IF Compte >= 20 THEN WriteoK = Compte .2
	
	Goto Test		'Attendre relâchement bouton ...
	
Endif	
	
	IF Compte > 250 OR Compte < 20 Then mainloop
	
	IF Compte >= 80 Then
	 
		pos = 1500 
		Goto Save	'remise au Neutre

	Endif	

					'Position "moyenne"


Save:

WRITE 1, Pos.HighByte			' 10ms
WRITE 2, Pos.LowByte			' 10ms

	Posn = pos
	Gosub Outsig

For delay = 1 to 25
	
	WriteoK = 1
	Gosub Outsig
	Pause 18
	
Next Delay
	
	Goto mainloop


	
'*****************************************************************************
Outsig:

Select Case pos			'Allumage Bargraph

	Case 750
	
		PortB = %01100001

	Case is <= posn - 635
	
		PortB = %01000000
		
	Case is <= posn - 519
	
		PortB = %01100000
		
	Case is <= posn - 404
	
		PortB = %00100000
		
	Case is <= posn - 288
	
		PortB = %00110000
		
	Case is <= Posn - 173	
	
		PortB = %00010000
		
	Case is <= Posn - 58
	
		PortB = %00011000
		
	Case is <= Posn
	
		PortB = %01001000
		
'*****************************************************************************		
	Case posn					' Position centrée
	
		PortB = %01001001
'*****************************************************************************
			
	Case is <= posn + 58
	
		PortB = %00001001
		
	Case is <= posn + 173
	
		PortB = %00001100
		
	Case is <= posn + 288
	
		PortB = %00000100
	
	Case is <= posn + 404
	
		PortB = %00000110
			
	Case is <= posn + 519
	
		PortB = %00000010
		
	Case is <= posn + 635
	
		PortB = %00000011
		
	Case is < posn + 750
	
		PortB = %00000001
		
	Case 2250
	
		PortB = %01000011
		
END Select
		
Low Signal
Pulsout Signal, pos /2		'Envoi Signal servo

RETURN

END

The "important" sections have been Highlighted ...

Here, the more the pressing UP and DOWN buttons speed up the 'count speed' ... pressing "prog" permits to choose beetween options ...
Note WriteOk is a led that shows the delay increasing value when pushing the button ...

Alain

**vtt-info** · - 15th January 2008, 17:37

Hi, Alain,

thanks for the fast reaction and the Code sample.

I would like to build a "One Button Dimmer"

1. Short Press Button T1: Toggle LED1 on/off or off/on.

2. Long Press Button T1: Ramp the Light von LED1 up or Ramp the Light down depending on the one last "Long Press", Ramp direction toggle every "Long Press".

3. Before power off store the last Ramp value

See the schematic in the attachment

Every help is welcome,

Konrad

**Acetronics2** · - 16th January 2008, 10:25

Hi, Vtt

A look Here, may be ...

http://www.electronique-diffusion.fr...lb0587&x=2&y=8

...

some chips still on the market !!! ... and in my drawers ... LOL !

Alain

**CuriousOne** · - 23rd March 2020, 19:01

Due to my lack of knowledge, when facing same problem, I did the following - while user keeps button pressed, value of needed variable is being increased and value of waiting variable reset. As user releases the button, waiting variable is being increased, and after it reaches some value (say for 2 seconds), next chunk of code is required. I'd like to do the same with long press, but still can't figure how.

Any ideas to add long press detection to this code?

Code:

setuploop:
if but2=0 then
dlycnt=dlycnt+1 'increase debounce variable while button is pressed

pause 1
endif

if BUT2=1 and dlycnt>100 then 'if button pressed long enough
dlycnt=0
high buz 'enable buzzer pin
menuitem=menuitem+1
lcdout $fe,1, #menuitem, " pressed "
pause 5
low buz 'disable buzzer
endif
goto setuploop

**mpgmike** · - 24th March 2020, 23:45

IF Button = Pressed THEN
WHILE Button = Pressed
LOOP
ENDIF

**CuriousOne** · - 25th March 2020, 06:26

I did it in the different way:

Code:

setuploop:
if but2=0 then
dlycnt=dlycnt+1 'increase debounce variable while button is pressed
ticker=ticker+1
pause 1
endif
if ticker>1500 and  BUT2=0 then gasvla 'if long pressed, then exit and (or) go to selector item
if BUT2=1 and dlycnt>100 then  'if short pressed, then do the rap
ticker=0
dlycnt=0
menuitem=menuitem+1  'this is incremental variable, substitute another next time you need it
lcdout $fe,$c0, " selection: " #menuitem," "  'debug just for case
pause 1
endif
goto setuploop

**amgen** · - 26th March 2020, 23:19

I did a setup to check for...... short press, then 2 second or 5 second then long press to enter program mode, for next for the timing, then go on to next check and goto's

Code:

 FOR A1= 1 TO 5        '<.1 SECONDS FOR TIMER
 PAUSE 3 
 GOSUB RDSW
 if SWCH=0 then start
 NEXT A1
 HIGH 2
read 1,A4 :PAUSE 10: C1=60*A4:C2=C1      
                    
 FOR A1 = 1 TO 100       '2 SECONDS FOR 8 HR
 PAUSE 8
 GOSUB RDSW
 if SWCH=0 then TIMER
 NEXT A1
 C1=28800      '8 HRS
 HIGH 5                       
 
 FOR A1 = 1 TO 100        'CHECK FOR PROGRAM 5 SEC TOTAL
 PAUSE 40
 GOSUB RDSW
 if SWCH=0 then TIMER
 NEXT A1 
 LOW 2:GOTO PROGRAM

Thread: Single button function

Thread Tools

Search Thread

Display

Hybrid View

Slb 0587

Re: Slb 0587

Re: Single button function

Re: Single button function

Re: Single button function

Similar Threads

Sony SIRC IR Issue

3 HPWM channels

Code check -- button not working

Pushbutton code routine suggestions?

Button subfunction 16F628

Members who have read this thread : 2

Bookmarks

Bookmarks

Posting Permissions