Digital touch Screen Combination lock

[richard]

i just can't help myself covid19 mania has set in

my take

'*  Notes   : This is a codelock based on the following components    *
'*          : PIC18F26K22 @ 64Mhz                                     *
'*          : 4D Systems ULCD 32DT diablo                             *
'*              note chksum untested                                  *
'**********************************************************************     
#CONFIG
  CONFIG  FOSC=INTIO67, PLLCFG=OFF, PRICLKEN=OFF, FCMEN=OFF, IESO=OFF
  CONFIG  PWRTEN=OFF, BOREN=SBORDIS, BORV=190, WDTEN=ON, WDTPS=32768
  CONFIG  CCP2MX=PORTC1, PBADEN=OFF, CCP3MX=PORTB5, HFOFST=ON, T3CMX=PORTC0
  CONFIG  P2BMX=PORTB5, MCLRE=EXTMCLR, STVREN=ON, LVP=OFF, XINST=OFF, DEBUG=OFF
  CONFIG  CP0=OFF, CP1=OFF, CP2=OFF, CP3=OFF, CPB=OFF, CPD=OFF, WRT0=OFF
  CONFIG  WRT1=OFF, WRT2=OFF, WRT3=OFF, WRTC=OFF, WRTB=OFF, WRTD=OFF, EBTR0=OFF
  CONFIG  EBTR1=OFF, EBTR2=OFF, EBTR3=OFF, EBTRB=OFF
#ENDCONFIG

define  OSC 64 
OSCCON    = $70   ; 64Mhz
OSCTUNE.6 = 1     ; Enable 4x PLL

while ! osccon2.7 :WEND ; to make sure the pll has stabilised before you run any other code 
  
TRISB = %10111111   
TRISC = %10111111 
ansela=0
anselb=0
anselc=0 

DEFINE HSER_RCSTA 90h ' Enable serial port & continuous receive
DEFINE HSER_TXSTA 24h ' Enable transmit, BRGH = 1
DEFINE HSER_CLROERR 1 ' Clear overflow automatically
DEFINE HSER_SPBRG 138 ' 115200 Baud @ 64MHz, -0.08%
SPBRGH = 0
BAUDCON.3 = 1         ' Enable 16 bit baudrate generator

DEFINE HSER2_RCSTA 90h ' Enable serial port & continuous receive
DEFINE HSER2_TXSTA 24h ' Enable transmit, BRGH = 1
DEFINE HSER2_CLROERR 1 ' Clear overflow automatically
DEFINE HSER2_SPBRG 160 ' 38400 Baud @ 64MHz, -0.08%
SPBRGH2 = 1
BAUDCON2.3 = 1         ' Enable 16 bit baudrate generator 

DATAIN          var byte[5] ;key pkt
pword           var byte[4] ;holds password
pbuff           var byte[4] ;ringbuffer  must be pow of 2
buff            var byte[4] ;buffer to test password input
pbuffinx        var byte    ;ringbuffer index
chksum          var byte    ;the key pkt checksum if used
key             var byte    ;the key just read in
i               var byte


;num1    data  "070D0000313B" ; this is number 1
;num2      data  "070D00003238" ; this is number 2
;num3    data  "070D00003339" ; this is number 3
;num4    data  "070D0000343E" ; this is number 4
;num5    data  "070D0000353F" ; this is number 5
;num6    Data  "070D0000363C" ; this is number 6
;num7    Data  "070D0000373D" ; this is number 7
;num8    Data  "070D00003832" ; this is number 8
;num9    data  "070D00003933" ; this is number 9
;num10   data  "070D00002A20" ; this is number *
;num11   data  "070D0000303A" ; this is number 0
;num12   data  "070D00000802" ; this is go
pause 1000
HSERout2 ["ready"]   ;debug
arraywrite pword ,["*478"]  ;set password  
pbuffinx = 0

Start:
gosub readkey 
    if key != 8 then              ;not go key
        HSERout2 [key]            ;debug
        pbuff[pbuffinx] = key     ;add key to ringbuffer
        pbuffinx = (pbuffinx+1)&3 ;inc ringbuffer index
    else                          ;is go key
        for i = 0 to 3            ;read ringbuffer into buffer
            buff[i] = pbuff[(pbuffinx+i)&3]
        next
        HSERout2 [13,10,str buff\4,13,10];debug
        ARRAYREAD buff,4,fail,[WAITSTR pword\4]  ;test password
        goto unlocked
    endif
    goto start
unlocked:
    HSERout2 ["unlocked"] ;debug
    pbuffinx = 0  ;may not be needed
    goto start
fail:
    pbuffinx = 0  ;may not be needed
    HSERout2 ["failed"]  ;debug
goto start

readkey:         ;read key pkt
    HSERIN [WAIT($07), str datain\5] 
'    chksum=7               ;chksum untested proteus vterminal won't allow null chr to be sent
'    for i=0 to 4
'        chksum  =  chksum ^ datain[i] 
'    next
'    if    chksum  then  goto readkey  ;dud read
    key = datain[3]
return

[astanapane]

Hi Richard,

thanks so much for your help and time. I need to read carefully your code and understand it.

right now i'm testing the circuit.

The unused pins either i will pull them up with a resistors, or i will make ports outputs and set them to low.

I see in your code you have made those unused pins as inputs.

[richard]

The unused pins either i will pull them up with a resistors, or i will make ports outputs and set them to low.


I see in your code you have made those unused pins as inputs.

my answer is the same as you asked last time-


if your program if affected by unused pins then your program is defective.


when bread boarding unused pins left as inputs are less likely to be damaged by
inadvertent connection.


chip current consumption can be reduced by not having floating pins (by a few micro amps).
enabling weak pull on unused inputs will stop them floating but consumes a few micro watts.
setting unused pins low and as output consumes the minimal possible micro watts.
the same can be achieved leaving them as input but physically grounding them.

if the project is to be battery driven i will worry about unused pins in the final production version
otherwise it is of no consequence.

[astanapane]

Richard, thanks once again.

The final version will be under a 12V power supply. So there is no problem thinking about power consumption.

Physically the final version might have resistors to unused pins pulled to +5V.

At the moment i'm testing the circuit on breadboard for 3 days and there is no problem at all.

P.S.

/Henrik.

EDIT: One more thing: You're clearly reading PORTB which must mean you're using those five low bits as inputs, yet, at the top of the program you have TRISB = %00000000 which makes all of PORTB outputs...

So if you use for example the "if"

if LATB.0 = 0

that mean that we make the port as input? If that so, then what is the way to read the status of the port...."high" or "low" or even the value of the port?

In the mean time im reading the manual.

[richard]

So if you use for example the "if"

if LATB.0 = 0
that mean that we make the port as input? If that so, then what is the way to read the status of the port...."high" or "low" or even the value of the port?

combined with this continually showing up in your code


TRISA = %00000000 'use TRISA to specify which pin is (1 = input) and which (0 = output) (ALL pins are output)
TRISB = %00000000 'use TRISB to specify which pin is (1 = input) and which (0 = output) (RB7 PORTB.7 is the RX input pin of the EUART, the rest are output)
TRISC = %10000000 'use TRISC to specify which pin is (1 = input) and which (0 = output) (RC7 PORTC.7 is the RX input pin of the EUART, the rest are output)
'in PORTC the RC3 attached is an LED.

'------------------------------------------------------------------------|
'--------------------------- TRIS A B C ---------------------------------|
'------------------------------------------------------------------------|
' PORTA.7  PORTA.6  PORTA.5  PORTA.4  PORTA.3  PORTA.2  PORTA.1  PORTA.0 |
'  bit7     bit6     bit5     bit4     bit3     bit2     bit1     bit0   |
'   0        0        0        0        0        0        0        0     |
'------------------------------------------------------------------------|
'------------------------------------------------------------------------|
' PORTB.7  PORTB.6  PORTB.5  PORTB.4  PORTB.3  PORTB.2  PORTB.1  PORTB.0 |
'  bit7     bit6     bit5     bit4     bit3     bit2     bit1     bit0   |
'   0        0        0        0        0        0        0        0     |
'------------------------------------------------------------------------|
'------------------------------------------------------------------------|
' PORTC.7  PORTC.6  PORTC.5  PORTC.4  PORTC.3  PORTC.2  PORTC.1  PORTC.0 |
'  bit7     bit6     bit5     bit4     bit3     bit2     bit1     bit0   |
'   1        0        0        0        0        0        0        0     |

leads me to think there is fundamental lack of understanding here of pic i/o architecture
and the relation ship between ansel,port,lat and tris registers and their effect on
pin operations.

i would recommend a few led flashing exercises to become comfortable with i/o concepts

[astanapane]

Hi Richard,

i will try some LED blinks for sure.

many thanks.

[richard]

contrary to popular belief its a tricky subject

lesson 1 what happens here with and without the nop compiled in ? and why ?

;rmw test ,a led with a  270 ohm resistor in series to gnd placed each on pin a0 and a1
#CONFIG
  CONFIG  FOSC = INTIO67
  CONFIG  PLLCFG = OFF
  CONFIG  PRICLKEN = ON
  CONFIG  FCMEN = OFF
  CONFIG  IESO = OFF
  CONFIG  PWRTEN = ON
  CONFIG  BOREN = SBORDIS
  CONFIG  BORV = 190
  CONFIG  WDTEN = ON
  CONFIG  WDTPS = 32768
  CONFIG  CCP2MX = PORTC1
  CONFIG  PBADEN = OFF
  CONFIG  CCP3MX = PORTB5                                
  CONFIG  T3CMX = PORTC0
  CONFIG  HFOFST = ON
  CONFIG  P2BMX = PORTB5
  CONFIG  MCLRE = EXTMCLR
  CONFIG  STVREN = ON
  CONFIG  LVP = OFF
  CONFIG  XINST = OFF
  CONFIG  DEBUG = OFF
  CONFIG  CP0 = OFF
  CONFIG  CP1 = OFF
  CONFIG  CP2 = OFF
  CONFIG  CP3 = OFF
  CONFIG  CPB = OFF
  CONFIG  CPD = OFF
  CONFIG  WRT0 = OFF
  CONFIG  WRT1 = OFF
  CONFIG  WRT2 = OFF
  CONFIG  WRT3 = OFF
  CONFIG  WRTC = OFF
  CONFIG  WRTB = OFF
  CONFIG  WRTD = OFF
  CONFIG  EBTR0 = OFF
  CONFIG  EBTR1 = OFF
  CONFIG  EBTR2 = OFF
  CONFIG  EBTR3 = OFF
  CONFIG  EBTRB = OFF
#ENDCONFIG
'    DEFINE DEBUG_REG PORTB
'    DEFINE DEBUG_BIT 7      ;  if not used for pwr  
'    DEFINE DEBUG_BAUD 9600
'    DEFINE DEBUG_MODE 0  
'  ASM




    ANSELA = 0
    DEFINE OSC 64 
    OSCCON = $70
    OSCTUNE.6 = 1
    TRISA = %11111100 
led1 var lata.0
led2 var lata.1


loopy:
lata=0
led2 = !porta.1
;@ nop
led1 = porta.1


pause 3000
 
goto loopy