Weird ADC / Math Results with 9-Bit PWM

[richard]

the fade will take 100mS what do you expect to see ?

' Fade in LED to set brightness
FOR i = 0 to 100 ; must match ARRAY SIZE of data table above
ReadCODE (DataTable + i), DataWord
PWMDuty = DataWord

GOSUB ChngLEDBrightness

pause 1
NEXT i

this is the only write to the lcd
what else do you expect ?

#IFDEF USE_LCD_FOR_DEBUG
HSEROUT [LCD_INST, LCD_CLR]
pause 5
HSEROUT ["i=",DEC i," "]
#ENDIF

the code is doing exactly what it should do , not what you hoping for maybe

[RossWaddell]

I expect something to show on the LCD, but it stays blank.

EDIT: I moved the LCD instructions to the loop to see what I could see and the final PWDuty value is 12291, way more than 512. The LED now ramps up in brightness but then drops down once the duty exceeds 512. I also needed to add a pause after the LCD initialization in order to see anything on the screen).

FadeInPause   CON 5         ; Pause during LED fade in

' Fade in LED to set brightness
FOR i = 0 to 100             ; must match ARRAY SIZE of data table above
    ReadCODE  (DataTable + i), DataWord
    PWMDuty = DataWord

    GOSUB ChngLEDBrightness 
         
    #IFDEF USE_LCD_FOR_DEBUG
        HSEROUT [LCD_INST, LCD_CLR]
        pause 5
        HSEROUT ["PWMDuty=",DEC PWMDuty,"  "]
    #ENDIF
   
    pause FadeInPause
NEXT i

Where the heck is it getting 12291?

[richard]

FOR i = 0 to 100

there is only 100 entries in the table
0 -----to --- 99

[RossWaddell]

there is only 100 entries in the table
0 -----to --- 99

Ugh. Of course. Now it works perfectly, with a final PWM duty cycle of 511.

[RossWaddell]

In case anyone is interested in the final working code (using linearization correction):

' For production version of this code, comment out the line below re:
' LCD debugging and also update config fuses to have code protect on
#DEFINE USE_LCD_FOR_DEBUG     ; comment out for non-debug use

' The PWM/fade works perfectly when **not** connected to a FET
'   - if using a FET, the LEDs 'pulse' and blink but don't fade in/out
'   - use a 2N2222A transistor

' ***************************************************************
' Pin Connections
' ***************************************************************

' VDD    -> pin 1            -> +5V
' RA5/Rc -> pin 2            -> EUSART receive
' RA2    -> pin 5            -> 1kohm -> 2N2222A transistor -> LEDs
' RA1    -> pin 6            -> Trim pot input
' RA0/Tx -> pin 7            -> EUSART transmit (LCD)
' VSS    -> pin 8            -> GND

DEFINE OSC 16               ; Set oscillator 16Mhz

' ***************************************************************
' EUSART Settings for Tx/Rc (e.g. LCD)
' ***************************************************************

' > use Mister E PIC Multi-Calc application to get register/DEFINE settings
' > as the values are dependent on the OSC and desired baud rate

DEFINE HSER_RCSTA 90h      ' Enable serial port & continuous receive
DEFINE HSER_TXSTA 24h      ' Enable transmit, BRGH = 1
DEFINE HSER_CLROERR 1      ' Clear overflow automatically
DEFINE HSER_SPBRG 160      ' 9600 Baud @ 16MHz, -0.08%

' ***************************************************************
' Device Fuses
' ***************************************************************
' PIC chip data sheets can be found here: C:\Program Files\Microchip\MPASM Suite

#CONFIG
   __config _CONFIG1, _FOSC_INTOSC & _WDTE_ON & _PWRTE_ON & _MCLRE_OFF & _CP_OFF & _CPD_OFF
   __config _CONFIG2, _PLLEN_OFF & _STVREN_ON & _BORV_LO & _LVP_OFF
#ENDCONFIG

' ***************************************************************
' Initialization
' ***************************************************************

OSCCON    = %01111000        ' 16MHz internal osc
pause 100                    

APFCON.2  = 0                ; Tx on RA0 for LCD display
APFCON.7  = 1                ; Rc on RA5
APFCON.0  = 0                ; CCP1 on RA2

' Some LCD serial modules need inverted data, some do not
' Enable the line below if needed, but for SparkFun SerLCD it should be
' commented out

'BAUDCON.4 = 1               ; Transmit inverted data to the Tx pin  

' From Mister E's Multi-Calc for EUSART:
' *****************************************************************
SPBRGH    = 1
BAUDCON.3 = 1                ' Enable 16 bit baudrate generator
' *****************************************************************

TRISA     = %00100010	     ' Make all pins output except for RA1 (trim pot input)
                             ' and RA5 (EUSART Rc)
ANSELA    = %00000010        ; Analog on PORTA.1 (AN1) only

FVRCON    = 0                ' Fixed Voltage Reference is disabled
ADCON0    = %00000101        ' ADC (analog-to-digital) is enabled on AN1 (RA1) only
PAUSEUS 20                   ; wait for the analog switch 'glitch' to die down
ADCON1    = %00110000        ; Left-justified results in 8-bits; Frc as timer

#IFDEF USE_LCD_FOR_DEBUG
    LCD_INST   CON 254       ' instruction
    LCD_CLR    CON 1         ' Clear screen
    LCD_L1     CON 128       ' LCD line 1
    LCD_L2     CON 192       ' LCD line 2
    LCD_SP_CMD CON 124       ' special command character (for adjusting backlight brightness or toggling splash screen)
    LCD_BR_LVL CON 140       ' 140==40%
    LCD_SPLASH CON 9         ' toggles splash screen display
#ENDIF

' Values generated by C:\Users\Ross\Dropbox\PBP Projects\PBP3 and MCSPX Software\LEDGammaCorrectGenerator.xlsm
' Array size = 100
' Total PWM steps: 512
' Gamma correction: 0.75 (try values in the range of 0.5 - 2.0)
' # of values per line: 15

'-----[The data table]--------------------------------------------------------
DataWord       VAR WORD
numSteps       CON 100
DataTable      CON EXT
GOTO OverData                ; Make sure data doesn't try to execute
ASM
DataTable
  DW   0,  1,  1,  2,  2,  2,  2,  2,  3,  3,  3,  3,  4,  4,  4
  DW   5,  5,  5,  6,  6,  7,  7,  8,  8,  9,  9, 10, 11, 12, 12
  DW  13, 14, 15, 16, 17, 18, 19, 20, 22, 23, 24, 26, 27, 29, 31
  DW  32, 34, 36, 38, 41, 43, 45, 48, 51, 54, 57, 60, 63, 66, 70
  DW  74, 78, 82, 87, 91, 96,101,107,112,118,124,131,138,145,152
  DW 160,168,177,186,196,205,216,227,238,250,263,276,289,304,319
  DW 334,351,368,386,404,424,445,466,488,511
endasm
OverData:
'-----[Continue with code]----------------------------------------------------

' Should only need to do this one time to adjust backlight brightness
'#IFDEF USE_LCD_FOR_DEBUG
'    HSEROUT [LCD_SP_CMD, LCD_BR_LVL]
'    PAUSE 5
'#ENDIF

' Should only need to do this one time to disable splash screen
'#IFDEF USE_LCD_FOR_DEBUG
'    HSEROUT [LCD_SP_CMD, LCD_SPLASH]
'    PAUSE 5
'#ENDIF

#IFDEF USE_LCD_FOR_DEBUG
    pause 1000
    HSEROUT [LCD_INST, LCD_CLR, "LCD Init"]
    pause 5
    HSEROUT [LCD_INST, LCD_L2, "  SerLCD_V2_5"]
    pause 2000
#ENDIF

' ***************************************************************
' Set up PWM on CCP1
' ***************************************************************

CCP1CON = %00001100          ; Use CCP1 in PWM mode

' Set duty cycle registers initially to 0
CCP1CON.4 = 0
CCP1CON.5 = 0
CCPR1L    = 0

' Use Mister E's PICMultiCalc_1.3.1.exe application (Windows only)   
' to determine prescaler and PR2 values for given OSC frequency (e.g. 16Mhz)
' and duty cycle (use 100% to see highest actual value)

' ************************
' CCP1 uses TMR2
' ************************
                       
T2CON   = %00000110         ; Timer2 on with 1:16 prescaler
PR2     = 127               ; For 16Mhz OSC the desired output freq of 1954Hz
                            ; is achieved with this PR2 value (9-bit resolution
                            ; with 1:16 prescaler)
                            ; MAX DUTY = 512; must match max PWM steps from data
                            ; table above
                            
PWMDuty       VAR WORD      ; Duty cycle variable for PWM

MaxADCVal     CON 255       ; 255 for 8-bit; 1023 for 10-bit

ADCInVal      VAR BYTE      ; stores ADCIN result read from trim pot
compVal       VAR BYTE      ; stores last-changed ADC value

CounterA      var BYTE		' Just a BYTE Temporary working variable
DataW         var WORD		' Just a WORD Temporary working variable
RawData       var BYTE [16] ' Array holding ADC Result

LEDBrIndx     VAR WORD

i             VAR WORD

LCDPause      CON 5         ; Pause for LCD display
FadeInPause   VAR BYTE      ; Pause during LED fade in
#IFDEF USE_LCD_FOR_DEBUG
    FadeInPause = 12
#ELSE
    FadeInPause = 12 + LCDPause
#ENDIF

' ************************************************
' Get Vref from ADC to set brightness step index
' ************************************************ 
GOSUB Do_ADC
compVal = ADCInVal          ; set initial compare value
GOSUB Map_ADCInVal_to_PWM_Steps

#IFDEF USE_LCD_FOR_DEBUG
    HSEROUT [LCD_INST, LCD_CLR]
    pause 5
    HSEROUT ["LEDBrIndx=",DEC LEDBrIndx,"  "]
    pause 750
#ENDIF

' Fade in LED to set brightness
FOR i = 0 to (LEDBrIndx  - 1)      ; max is 'numSteps' from data table above
    ReadCODE  (DataTable + i), DataWord
    PWMDuty = DataWord

    GOSUB ChngLEDBrightness 
         
    #IFDEF USE_LCD_FOR_DEBUG
        HSEROUT [LCD_INST, LCD_CLR]
        pause 5
        HSEROUT ["PWMDuty=",DEC PWMDuty,"  "]
    #ENDIF
   
    pause FadeInPause
NEXT i

Main:
    GOSUB Do_ADC
    PAUSE 100

    If (compVal > (ADCInVal + 1)) or (compVal < (ADCInVal - 1)) THEn
        compVal = ADCInVal
        GOSUB Map_ADCInVal_to_PWM_Steps

        ReadCODE  (DataTable + (LEDBrIndx - 1)), DataWord
        PWMDuty = DataWord

        gosub ChngLEDBrightness

        #IFDEF USE_LCD_FOR_DEBUG
            HSEROUT [LCD_INST, LCD_CLR]
            pause 5
            HSEROUT ["new LEDBrIndx", LCD_INST, LCD_L2, DEC LEDBrIndx, "  "]
        #ENDIF
    ENDIF
GOTO Main

Do_ADC:
'	Stuff 16 Element WORD Array full of ADC values
'	----------------------------------------------
	For CounterA = 0 to (16 - 1)
        ADCON0    = %00000101 ' Select Channel, Turn-On A/D
						      '	7=0 Unused
						      '	6=0 Unused
						      '	5=0 )
						      '	4=0 )
						      '	3=0 ) selects AN1
						      '	2=0 )
						      '	1=0 Go-done Bit
						      '	0=1 switch-On ADC Module
		Pauseus 50			     ' Wait for channel to setup
        ADCON0.1 = 1			 ' Start conversion
		While ADCON0.1=1:Wend	 ' Wait for conversion
'		DataW.HighByte=ADRESH	 
'		DataW.LowByte=ADRESL
        DataW = ADRESH           ' Read variable from ADC and save
		RawData(CounterA) = DataW

	Next CounterA

'	Sort ADC Input
'	--------------
	CounterA = 0
 
 GetADCSortLoop:

	If RawData(CounterA + 1) < RawData(CounterA) then
		DataW = RawData(CounterA)
		RawData(CounterA) = RawData(CounterA+1)
		RawData(CounterA+1) = DataW
		If CounterA > 0 then CounterA = CounterA - 2
	endif
	CounterA=CounterA+1
	If CounterA < (16 - 1) then goto GetADCSortLoop

'	Quanticise, discarding top and bottom FOUR elements
'	----------------------------------------------------
	DataW = 0
	For CounterA = 4 to 11
		DataW = DataW+RawData(CounterA)
	Next CounterA
	
    ADCInVal = DataW>>3			' Divide Result by EIGHT

return

'*********** Map Vref to PWM step **************************************
Map_ADCInVal_to_PWM_Steps:
'   Arduino Map function to emulate:
'   ===============================
'   map(value, fromLow, fromHigh, toLow, toHigh)

'   long map(long x, long in_min, long in_max, long out_min, long out_max)
'   {
'     return (x - in_min) * (out_max - out_min) / (in_max - in_min) + out_min;
'   }

'   Need to split up the operations to get full value using DIV32
    LEDBrIndx = ((compVal - 0) * (numSteps - numSteps/2))
    LEDBrIndx = DIV32 (MaxADCVal - 0) + numSteps/2

RETURN

'*********** Set duty registers ****************************************
ChngLEDBrightness:
    CCP1CON.4 = PWMDuty.0
    CCP1CON.5 = PWMDuty.1
    CCPR1L    = PWMDuty >> 2
    
RETURN

I've also attached my Microsoft Excel workbook which calculates the LED linearization:
LEDGammaCorrectGenerator.xlsm.zip

[Dave]

Ross, Attached is the Gamma table I came up with some years ago. Enjoy...