Pic 18f Usb

[Tissy]

Hi Bruce,

I have now ordered the book as you recommended, i'm sure it will come in very handy.

I have figured out that if you use EasyHID to set the maximum Buffer size to 32, then you can increase the amount of outputs on the PIC that you can set HIGH or LOW. ie the PIC side is odd numbers 1 - 31 and the VB side is even numbers 2 - 32.

ie on the PIC side requires:

PORTC.1 = USBBuffer[23]

where as on the VB side requires:

BufferOut(24) = 1 ' LED on

If i want to use all of PORTA and PORTB, is there an easy way of listing these in the two codes, or do they have to be done seperately? ie:

PIC
PORTA.1 = USBBuffer[1]
PORTA.2 = USBBuffer[3]
PORTA.3 = USBBuffer[5]
PORTA.4 = USBBuffer[7]
PORTA.5 = USBBuffer[9]

VB
BufferOut(2) = 1 ' LED on
BufferOut(4) = 1 ' LED on
BufferOut(6) = 1 ' LED on
BufferOut(8) = 1 ' LED on
BufferOut(10) = 1 ' LED on

Moving on from the switching of outputs HIGH or LOW, how would one send say text from the PIC to a text box in VB. For example, on the PIC, if a certain routine is executed, it sends a command to the VB application which is then displayed in a text window. Or is this getting too advanced for a quick explanation??

Thanks again for you assistance,

Steve

[andresnavas]

Hello. I don't know what happend but my EasyHID only create 4 files:
DESCUSBProject.asm
USBDESC.asm
USBProject.asm
USBProject.pbp

What i doing wrong? why it don't creat the other files like the USB18.c

Thanks for yours help!!!

Please if somebody have any example send it to me at: [email protected]

Thanks!

[Tissy]

andresnavas,

I have sent the reply straight to your personal email address. It would appear that the files aren't generating properly. All i can suggest is check the compilation settings again. If that doesn't work, try installing the application again.

I certainly haven't had any problems like that.

Within the directory you specified in the project settings (default is C:\Program Files\Mecanique\EasyHID\) should see another directory as per your title, such as USBProject. Within that directory is 2 sub directories, one for the VB or C code and one for the Proton or PICBasic code.

I have sent you a zip file containing what you should expect to see for a default VB and PICBasic code using the PIC18F4550 also with all the default settings.

Hope this helps,

Steve

[judy]

Hi all,

Absolutely brilliant thread, a lot of quality info and best of all can be done fast, cheers to all those involved. I am really new to this interfacing stuff, so if I'm asking too much or the newbie stink is unbearable, feel free to tell me to sling my hook.

I was wondering how one would go about changing the HID code provided by Easy HID USB code generator to simply read in up to three pulse width inputs (as far as I know the digital ins on the 18f2455 support this) and up to three analog ins through on board adc (ideally varying between -3 to +3v) simultaneously and as fast as possible, in fact how many samples per second is possible using the HID approach? Sin e.

I would greatly appreciate any help with this/direction to where help should be sought.

Thanks in advanced
Judy

[Bruce]

Steve,

You're dealing with bytes. PORTA.1 = USBBuffer[1] isn't the way to go since you can't place a byte value on a single port "bit".

Just place the byte you need on the whole port. You can send a single byte value from the PC app, and simply place it on the port.

I.E. PORTA = USBBuffer[1] should work fine - assuming that's the byte element you want.

Sending data from the PIC to PC is equally simple. Here's one example. Note this isn't everything. Just the sections I added to the framework file created with EasyHID.

DEFINE OSC 48
DEFINE LOADER_USED 1
DEFINE	ADC_BITS 10     ' Set number of bits in result
DEFINE	ADC_CLOCK 3     ' Set clock source /32
DEFINE	ADC_SAMPLEUS 50 ' Set sampling time in uS
DEFINE RESET_ORG 800h ' <-- I used the Microchip USB loader

BufferSize      con 8
DataBuffer      Var Byte(BufferSize) ' data buffer
DataBufferCount Var Byte             ' buffer size
Quanta  con 1251
TRISD = 0
PORTD = 0

' Variables
X       VAR byte
Adval   VAR WORD
   
    TRISA.0 = 1        ' RA0 input
    ADCON1 = %00001110 ' A/D channel 0
    ADCON2 = %10000011 ' Right justify for 10-bit
    USBInit

Main:
    GOSUB DoUSBIn
    PORTD = DataBuffer[7]
    
    ADCIN 0,adval		     ' Read A/D channel 0 into ADval variable
    ADval = ADval */ Quanta  ' Quanta result
    
    ' Load data buffer
    DataBuffer(0) = Adval DIG 3
    DataBuffer(1) = "."
    DataBuffer(2) = Adval DIG 2
    DataBuffer(3) = Adval DIG 1
    DataBuffer(4) = Adval DIG 0
    GOSUB DoUSBOut
    FOR X = 0 to 99 ' Short delay between updates
     PAUSEUS 1000
     USBSERVICE     ' Maintain HID connection during delay period
    NEXT X
    GOTO Main

On the PC side, modify the USB framework file created with EasyHID something like this;
Dim MyText As String ' create your string storage space

In the OnRead sub-routine;
MyText = (CStr(BufferIn(1)) + Chr$(BufferIn(2)) + CStr(BufferIn(3)) + CStr(BufferIn(4)) + CStr(BufferIn(5)) + "V")
Label1.Caption = MyText ' Place string text into label displaying A/D value

Judy,

Reading three pulse widths or A/D values doesn't really have anything to do with USB. The USB PIC is just another PIC with the addition of the USB module. Using the onboard A/D is pretty much the same as any other PIC.

All you need here is the datasheet, and a little time to experiment getting your pulse measurement & A/D routines working. Sending this all to the PC via the USB module is no more than stuffing your values into the outgoing buffer like in the previous example.

Just be sure to keep the USB connection alive by avoiding the use of blocking functions, long delays, etc,,. It's really not that hard, but you will need to experiment a tad.

[Tissy]

Bruce,

Would you mind posting all of your ADC code, i am getting errors. I've had a look, but can't figure it out.

The code posted above seems to be missing the DoUSBIn and DoUSBOut subroutines.

I also get an error on the DataBuffer(1) = "."

I want to use it as a 5v voltage monitor passing the results to Vb.

Many thanks,

Steve

[Bruce]

Hi Steve,

Sure. Here's the complete file. Just be sure you've used EasyHID to generate the required USB support files.

DEFINE LOADER_USED 1
DEFINE OSC 48
DEFINE ADC_BITS 10     ' Set number of bits in result
DEFINE ADC_CLOCK 3     ' Set clock source /32
DEFINE ADC_SAMPLEUS 50 ' Set sampling time in uS
DEFINE RESET_ORG 800h    ' For Microchip USB loader

BufferSize      con 8
DataBuffer      Var Byte(BufferSize) ' data buffer
DataBufferCount Var Byte             ' buffer size
Quanta  con 1251
TRISD = 0
PORTD = 0

' Variables
X       VAR byte
Adval   VAR WORD
   
    TRISA.0 = 1        ' RA0 input
    ADCON1 = %00001110 ' A/D channel 0
    ADCON2 = %10000011 ' Right justify for 10-bit
    USBInit

Main:
    GOSUB DoUSBIn
    PORTD = DataBuffer[7]
    
    ADCIN 0,Adval		 ' Read A/D channel 0 into ADval variable
    ADval = ADval */ Quanta  ' Quanta result
    
    ' Load data buffer
    DataBuffer(0) = Adval dig 3
    DataBuffer(1) = "."
    DataBuffer(2) = Adval DIG 2
    DataBuffer(3) = Adval DIG 1
    DataBuffer(4) = Adval DIG 0
    GOSUB DoUSBOut
    FOR X = 0 to 99 ' Short delay between updates
     PAUSEUS 1000
     USBSERVICE     ' Maintain HID connection during delay period
    NEXT X
    GOTO Main

   ' USB in...
DoUSBIn:
    DataBufferCount = BufferSize
    USBService
    USBIn 1, DataBuffer, DataBufferCount, DoUSBIn
    RETURN
   
   ' USB out...
DoUSBOut:
    DataBufferCount = BufferSize
    USBService
    USBOut 1, DataBuffer, DataBufferCount, DoUSBOut
    RETURN
    
    END

Here's the PIC & VB source for a USB A/D datalogger http://www.rentron.com/mcstudio/USB_AD.zip

[Tissy]

Great, thanks Bruce. Unfortuanatly i am still getting a big 0 in VB. I'm sure its only something small i am doing wrong (hopefully) !!

Here is the code, can you spot anything obvious that i have done wrong?

Its a PIC18F2455 where i am putting 5v onto RA0.

DEFINE LOADER_USED 1
DEFINE OSC 48
DEFINE ADC_BITS 10     ' Set number of bits in result
DEFINE ADC_CLOCK 3     ' Set clock source /32
DEFINE ADC_SAMPLEUS 50 ' Set sampling time in uS
'DEFINE RESET_ORG 800h    ' For Microchip USB loader

BufferSize      con 8
DataBuffer      Var Byte(BufferSize) ' data buffer
DataBufferCount Var Byte             ' buffer size
Quanta  con 1251


' Variables
X       VAR byte
Adval   VAR WORD
   
    TRISA.0 = 1        ' RA0 input
    ADCON1 = %00001110 ' A/D channel 0
    ADCON2 = %10000011 ' Right justify for 10-bit
    USBInit

Main:
    GOSUB DoUSBIn
    PORTB = DataBuffer[7]
    
    ADCIN 0,Adval		 ' Read A/D channel 0 into ADval variable
    ADval = ADval */ Quanta  ' Quanta result
    
    ' Load data buffer
    DataBuffer(0) = Adval dig 3
    DataBuffer(1) = "."
    DataBuffer(2) = Adval DIG 2
    DataBuffer(3) = Adval DIG 1
    DataBuffer(4) = Adval DIG 0
    GOSUB DoUSBOut
 
    FOR X = 0 to 99 ' Short delay between updates
       PAUSEUS 1000
       USBSERVICE     ' Maintain HID connection during delay period
    NEXT X

 GOTO Main

' ************************************************************
' * receive data from the USB bus                            *
' ************************************************************
DoUSBIn:
    DataBufferCount = BufferSize
    USBService
    USBIn 1, DataBuffer, DataBufferCount, DoUSBIn
    RETURN
   
' ************************************************************
' * wait for USB interface to attach                         *
' ************************************************************
DoUSBOut:
    DataBufferCount = BufferSize
    USBService
    USBOut 1, DataBuffer, DataBufferCount, DoUSBOut
    RETURN
END

In VB, i have placed a label on the form and this is in the read event section

'*****************************************************************
' on read event...
'*****************************************************************
Public Sub OnRead(ByVal pHandle As Long)
   
   ' read the data (don't forget, pass the whole array)...
   If hidRead(pHandle, BufferIn(0)) Then
      
    MyText = (CStr(BufferIn(1)) + Chr$(BufferIn(2)) + CStr(BufferIn(3)) + CStr(BufferIn(4)) + CStr(BufferIn(5)) + "V")
    Label1.Caption = MyText ' Place string text into label displaying A/D value

      
      ' ** YOUR CODE HERE **
      ' first byte is the report ID, e.g. BufferIn(0)
      ' the other bytes are the data from the microcontrolller...
   End If
End Sub

Many thanks again.

Steve