I originally installed version 8.63, uninstalled it and installed version 8.60. still with same problem. here is my PBPMPLAB.BAT file.. same as yours:
Code:
@echo off
setlocal enabledelayedexpansion 

:: This file is intended to be run from MPLAB for compilation
:: using the PICBASIC PRO Compiler.  PBPMPLAB.BAT should be
:: located in the PBP install folder (default C:\PBP). 

:: Set for default location on 32-bit systems
SET MPASMWIN_PATH=C:\Program Files\Microchip\MPASM Suite

:: If that doesn't work, set for default location on 64-bit systems
IF NOT EXIST "!MPASMWIN_PATH!\MPASMWIN.EXE" (
SET MPASMWIN_PATH=C:\Program Files ^(x86^)\Microchip\MPASM Suite
)
  
::*************** User modifications here ***************************


:: In order for PBP to launch the MPASMWIN Assembler, the 
:: location of MPASMWIN.EXE will be appended to the existing 
:: PATH  environment variable.  If MPASMWIN is not located in 
:: one of the default folders above, uncomment and change the
:: following line to reflect the true location:

rem   SET MPASMWIN_PATH=C:\Program Files ^(x86^)\Microchip\MPASM Suite


::*******************************************************************


:: Code below this point should not need to be modified.


IF NOT EXIST "!MPASMWIN_PATH!\MPASMWIN.EXE" (
	echo   MPASMWIN.EXE could not be found at:
	echo   !MPASMWIN_PATH!
	echo   In order for PBP to function from MPLAB, the path to 
	echo   MPASMWIN.EXE must be corrected by editing the file:
	echo   %0
	goto end
)

:: Append MPASM folder to existing PATH

set PATH=%PATH%;!MPASMWIN_PATH!

:: Set CURPATH to the location of this batch file.

set CURPATH=%~dp0

:: If -n parameter is present, run PBPL.EXE.  If not, run PBPW.EXE.

if %1 == -n (
	echo Executing: "%CURPATH:~0,-1%\PBPL.EXE" %2 %3 %4 %5 %6 %7 %8 %9
	"%CURPATH:~0,-1%\PBPL.EXE" %2 %3 %4 %5 %6 %7 %8 %9 
) else (
	echo Executing: "%CURPATH:~0,-1%\PBPW.EXE" %1 %2 %3 %4 %5 %6 %7 %8 %9 
	"%CURPATH:~0,-1%\PBPW.EXE" %1 %2 %3 %4 %5 %6 %7 %8 %9 
)

:end