16F1827 setup

[Acetronics2]

Ok ...

1) Did you make the mods Bruce pointed at in his 6th February post ???

you DO have to make them ...

Also, check your PI14EEXT.BAS to make sure it has APFCON0 VAR BYTE EXT and not
APFCON VAR BYTE EXT.

There should also be these definitions in the PI14EEXT.BAS file;

Code:
MDCON VAR BYTE EXT
MDSRC VAR BYTE EXT
MDCARH VAR BYTE EXT
MDCARL VAR BYTE EXT

If these aren't in there, just add them.

2) just Paste Bruce's code in MCS:

'****************************************************************
'****************************************************************
'*  Name    : DSM.BAS                                           *
'*  Author  : B. Reynolds                                       *
'*  Notice  : Copyright (c) 2010 http://www.Rentron.com         *
'*          : All Rights Reserved                               *
'*  Date    : 2/5/2010                                          *
'*  Version : 1.0                                               *
'*  Notes   : Using the 16F1827 Data Signal Modulator for IR    *
'*          : serial communications with onboard USART.         *
'****************************************************************

' MODOUT, RB3, outputs whatever you send with HSEROUT as a 40kHz
' modulated data stream. 

ASM
  __config _CONFIG1, _FOSC_INTOSC & _WDTE_OFF & _PWRTE_ON & _MCLRE_OFF & _CP_OFF & _CPD_OFF & _BOREN_ON & _CLKOUTEN_OFF & _IESO_OFF & _FCMEN_OFF
  __config _CONFIG2, _PLLEN_OFF & _LVP_OFF & _VCAPEN_OFF & _LVP_OFF & _STVREN_OFF
ENDASM

DEFINE OSC 8
DEFINE HSER_BAUD 2400  
Duty VAR WORD
TRISB = 0

Init:
  PR2 = 49             ' Set PWM for ~40kHz
  CCP1CON = %00001100  ' Mode select = PWM
  T2CON = %00000100    ' %00000100 = TMR2 ON 1:1 prescale

  Duty = 100           ' Roughly 50% duty cycle
  CCP1CON.4 = duty.0   ' Setup 10-bit duty cycle as
  CCP1CON.5 = duty.1   ' a 10-bit word
  CCPR1L = DUTY >> 2
  APFCON0 = 1          ' CCP1 PWM output on RB0
  OSCCON = %01110000   ' 8MHz internal
  ANSELA = 0           ' all digital. A/D disabled
  ANSELB = 0
  MDCON = %11100000    ' modulator, MODOUT pin, slew rate limiting enabled
  ' Note: set MDSRC.7 to eliminate the TX signal output on RB2/TX
  MDSRC = %00001010    ' USART TX is modulation source, TX output still active
  MDCARH = %00000000   ' carrier OFF during idle periods
  MDCARL = %00000100   ' carrier ON only when sending data

Main:
  HSEROUT [$55]        ' sends USART data out modulated at 40kHz
  PAUSE 50
  GOTO Main
  END

MUST compile without any error in MCS if 1) has been done.

As simple as that.

Alain

[Macgman2000]

Alain,

I recopied the code from your post. Still getting

Symbol not previously defined (PortC)
Symbol not previously defined (TRISC)
etc etc etc

[Acetronics2]

Hi,

Got it ...

Devices affected: 16F1826, 16F1827
Date encountered: 08/2009
Error class: safe (always reported)

There are invalid port aliases in the PBP header file for these parts. The following assembly errors will be generated:

Symbol not previously defined (PORTC)
Symbol not previously defined (TRISC)
Workaround:

Edit the files 16F1826.BAS and 16F1827.BAS (found in the PBP install folder) as follows:

PORTL VAR PORTB
PORTH VAR PORTA ' PORTC invalid, change to PORTA
TRISL VAR TRISB
TRISH VAR TRISA ' TRISC invalid, change to TRISA

This is from a Melab's errata sheet Darrel Pointed at some times ago ....
I made the mod a while ago ... so couln't see what's wrong.

Have a nice evening

Alain

[Macgman2000]

Alain,

Ok getting somewhere now. When I comment out all the fuse configurations between the ASM and ENDASM I get no errors. With all the mods that you suggested.

I am down to 3 errors.

overwriting previous address contents (8007)
symbol not previously defined (_CAPEN_OFF)
overwriting previous address contents (8008)

What other files do I have to modify to get rid of these errors?

Nick

[Macgman2000]

Alain & Bruce,

I almost resolved all the errors by modifying the files you and Bruce suggested, except for 1. I went into 16F1827.INC (PBP file) and commented out existing fuse settings and let the main code define those functions. So of the 3 remaining errors, 1 is left _VCAPEN_OFF symbol not previously defined.

I opened up the P16F1827.INC (MPASM file) to see if there is an address for _VCAPEN_OFF....it is not listed at all...not even under Config1 or Config2.

Wow this has been an uphill battle getting this thing to compile. Any suggestions on how to resolve this last issue would be appreciated.

thanks,
Nick

[Bruce]

Just remove _VCAPEN_OFF from your config line.

It's definitely in my P16F1827.INC file, but if Microchip has updated include files, it may
not be in the one you have. It should work either way.

[Macgman2000]

Bruce,

Thanks for the help. It compiled without errors. Now off to testing! I will post back my results later.

Nick

[Ioannis]

It's definitely in my P16F1827.INC file, but if Microchip has updated include files, it may
not be in the one you have. It should work either way.

Hi Bruce.

I searched on two MPLAB installations for this VCAPEN thing.

It is not in my *.inc files and also it is absent from the DS41391C pdf file too.

I wonder what is this for. Just curious.

Ioannis