COUNT is not counting again

[Bruce]

Non interrupt version;

  @ device  pic16F690, intrc_osc_noclkout, wdt_off, mclr_off, protect_off 
  K CON 15     ' Calibration factor for flow meter = # pulses per gal
  
' Setup Timer0 as an 8-bit counter with the clock input on RA2.
' 1:1 TMR0 prescaler
' TMR0 counts on high-to-low transitions
  OPTION_REG = %00111000
  
' A/D & Comparators disabled
  ANSEL=0           ' all digital
  ANSELH=0          ' analog module disabled
  CM1CON0=0
  CM2CON0=0
  
' Port setup
  PORTC = 0         ' LEDs off, PULSOUT RC3 provides a high-going pulse
  PORTA = 0
  TRISC = %11110000 ' lower 4 pins outputs
  TRISA = %11111111 ' RA2 = TMR0 clock input for simulated meter pulse inputs
  TMR0 = 0          ' clear TMR0 count       
  
Main:
  IF TMR0 < K  THEN
                    ' Keep the valve open...do nothing..let water flow
  ELSE
    TMR0 = 0        ' clear TMR0 count
    PULSOUT PORTC.3,1000  ' Generate required 10 msec pulse to RC3
   ' WRITE 7, TMR0   ' write count if you need to?
    HIGH PORTC.0    ' LED toggle stuff
    PAUSE 500
    LOW PORTC.0 
  ENDIF
  GOTO Main
  
  END

With DT interrupts; Note that now you need to use the MPASM
assembler & config settings for MPASM.

 @ __config _INTRC_OSC_NOCLKOUT & _WDT_OFF & _MCLRE_OFF & _CP_OFF
  
  INCLUDE "DT_INTS-14.bas"     ; Base Interrupt System
  INCLUDE "ReEnterPBP.bas"     ; Include if using PBP interrupts

ASM
INT_LIST  macro    ; IntSource,   Label,     Type, ResetFlag?
      INT_Handler    TMR0_INT,  _FlusO_Matic, PBP,  yes
    endm
    INT_CREATE               ; Creates the interrupt processor
ENDASM

  K CON 15     ' Calibration factor for flow meter = # pulses per gal
  
' Setup Timer0 as an 8-bit counter with the clock input on RA2.
' 1:1 TMR0 prescaler
' TMR0 counts on high-to-low transitions
  OPTION_REG = %00111000
  
' A/D & Comparators disabled
  ANSEL=0           ' all digital
  ANSELH=0          ' analog module disabled
  CM1CON0=0
  CM2CON0=0
  
' Port setup
  PORTC = 0         ' LEDs off, PULSOUT RC3 provides a high-going pulse
  PORTA = 0
  TRISC = %11110000 ' lower 4 pins outputs
  TRISA = %11111111 ' RA2 = TMR0 clock input for simulated meter pulse inputs
  TMR0 = 241        ' preload TMR0 to overflow after 15 counts
    
  @ INT_ENABLE TMR0_INT ; enable TMR0 counter interrupt
  
Main:
  PAUSE 1
  GOTO Main
  
FlusO_Matic:
  TMR0 = 241       ' reload TMR0 to overflow after 15 counts
  PULSOUT PORTC.3,1000  ' Generate required 10 msec pulse to RC3
 ' WRITE 7, TMR0   ' write count if you need to?
  @ INT_RETURN
  
  END

Then of course, you can do pretty much the same by just watching the Timer0
interrupt flag;

 @ device  pic16F690, intrc_osc_noclkout, wdt_off, mclr_off, protect_off 

  K CON 15     ' Calibration factor for flow meter = # pulses per gal
  
' Setup Timer0 as an 8-bit counter with the clock input on RA2.
' 1:1 TMR0 prescaler
' TMR0 counts on high-to-low transitions
  OPTION_REG = %00111000
  
' A/D & Comparators disabled
  ANSEL=0           ' all digital
  ANSELH=0          ' analog module disabled
  CM1CON0=0
  CM2CON0=0
  
' Port setup
  PORTC = 0         ' LEDs off, PULSOUT RC3 provides a high-going pulse
  PORTA = 0
  TRISC = %11110000 ' lower 4 pins outputs
  TRISA = %11111111 ' RA2 = TMR0 clock input for simulated meter pulse inputs
  TMR0 = 241        ' preload TMR0 to overflow after 15 counts
  
  TMRO_INT_FLAG VAR INTCON.2 ' Timer0 overflow flag bit   
  INTCON = 0        ' not using interrupts + clear Timer0 int flag
  
Main:
  WHILE TMRO_INT_FLAG = 0
  WEND
  PULSOUT PORTC.3,1000  ' Generate required 10 msec pulse to RC3
 ' WRITE 7, TMR0   ' write count if you need to?
  TMRO_INT_FLAG = 0 ' clear overflow flag
  TMR0 = 241        ' reload TMR0 to overflow after 15 counts
  GOTO Main
  
  END

And, last, but not least, there's the old stand-by ON INTERRUPT;

@ device  pic16F690, intrc_osc_noclkout, wdt_off, mclr_off, protect_off 

  K CON 15     ' Calibration factor for flow meter = # pulses per gal
  
' Setup Timer0 as an 8-bit counter with the clock input on RA2.
' 1:1 TMR0 prescaler
' TMR0 counts on high-to-low transitions
  OPTION_REG = %00111000
  
' A/D & Comparators disabled
  ANSEL=0           ' all digital
  ANSELH=0          ' analog module disabled
  CM1CON0=0
  CM2CON0=0
  
' Port setup
  PORTC = 0         ' LEDs off, PULSOUT RC3 provides a high-going pulse
  PORTA = 0
  TRISC = %11110000 ' lower 4 pins outputs
  TRISA = %11111111 ' RA2 = TMR0 clock input for simulated meter pulse inputs
  TMR0 = 241        ' preload TMR0 to overflow after 15 counts
  
  TMRO_INT_FLAG VAR INTCON.2 ' Timer0 overflow flag bit   
  INTCON = %10100000 ' enable global & Timer0 interrupt
  
  ON INTERRUPT GOTO FlushOMatic
  
Main:
  PAUSE 1
  GOTO Main
  
  DISABLE  
FlushOMatic:
  PULSOUT PORTC.3,1000  ' Generate required 10 msec pulse to RC3
 ' WRITE 7, TMR0   ' write count if you need to?
  TMRO_INT_FLAG = 0 ' clear overflow flag
  TMR0 = 241        ' reload TMR0 to overflow after 15 counts
  RESUME
  ENABLE
    
  END

All kept really simple & fairly easy to follow/modify...;o}

[jellis00]

Bruce, I really liked the code you posted for a Non-interrupt version to do my counting. I prefer it over the other options you posted, since I won't get into the problems I have seen in trying to handle interrupts in noisy signal envoirnments. It is concise with minimal executable statements, low memory requirement and should execute efficiently.
It looked to me like it should run with my PIC16F690 almost as is. So I set up a pinout so that my momentary push button switch that I have been using to simulate the external sensor pusles will connect the RA2 pin to ground each time I depress the switch. I presumed this would be enough of a "clock" transition to increment the TMR0 counter. However, I haven't yet been able to see it run since I am having a compile problem with assembler errors that I can't understand or trace. I am attaching a screen snapshot (.jpg image) that shows the errors in lower left. Can you clarify what these errors are telling me?

[Bruce]

Make sure you're using the PM assembler, and not MPASM. Or change to the MPASM
config line I've already shown in the DT interrupts version.

[jellis00]

Bruce,
OK, I am using PBP compiler via MicroStudio that uses MSPM assembler. So I made the config change. Now I get a different, but single assembler error: " Error[118]: Overwriting previous address contents[2007]" When I click on it, it points to the @__config statement.
Again I don't know what this is telling me...can you advise.
BTW, is there anywhere that you can get error listings for the MSPM assembler so you know what they mean?

[mister_e]

http://www.picbasic.co.uk/forum/showthread.php?t=11116

[jellis00]

Thanks, Mister e, for the link. The article by Melanie on how to set configuration fuses answered my error question and also a lot of others I have had about the subject. I edited my .incl file per her instructions to eliminate overwrite by the @__config statement and it now compiles without errors.
Now that it finally runs, I have another question for Bruce. The Non-interrupt code runs fine, but I am not seening any pulse counts show up in TMR0 value when I write it during execute and then use READ in PICKkit2 to read the memory address....it is continuously zero. I thought maybe it was because my simulation mode for pulses wasn't working so I put a voltmeter on the RA2 pin while running the program and depressing the switch button to simulate pulses. What I saw was that RA2 was at 1.8 volts when the switch was open and of course it went to ground when I depress it. Isn't the 1.8 volt transition enough to trigger the TMR0 to count the pulses?

[jellis00]

Bruce, I see now in 16F690 data sheet that for TTL the minimum Vih threshold is 2.0 volts and for Schmidt trigger it is 0.8 volts. Would my switch grounding interface appear to RA2 as TTL or Schmidt trigger? Since the RA2 input is 1.8 v when open and I am grounding it to create a simulated pulse, I don't know whether this is enough downward transition or not. If not, what can I do about it. I thought the open circuit voltage level of RA2 would be over 2.0 volts.

[Bruce]

Do you see where it states TMR0 = 0 ' clear TMR0 count

This clears the timer0 count. If you need to write the timer0 count value to EEPROM first,
then simply move the TMR0 = 0 below where you have WRITE 7, TMR0. Then you will clear
the TMR0 count after you write it to EEPROM.

It's not rocket science...;o}

A TTL input requires 2V to VDD. As long as power is 4.5V ≤ VDD ≤ 5.5V, which just means
VDD is greater than or equal to 4.5V and less than or equal to 5.5V. Then it meets the Vih
logic 1 threshold.

A Schmitt Trigger tytpe input requires 0.8V * VDD to VDD.

If you were operating from a 5V supply, then 0.8 * 5V = 4V, which is what you'll need to
apply as a minimum to the input for it to recognize a logic 1.

Ground is ground. Your switch is for sure taking the input to ground.

With 4.5V ≤ VDD ≤ 5.5V, Vil is met when the input is at Vss, up to 0.8V. But check the
column under Conditions to be sure. It varies a bit with different VDD levels.

Look at PINOUT DESCRIPTION – PIC16F690. Now look at RA2 for what type of input T0CKI
is under the Input Type column.

Now look at RA5. When you use RA5 as a general purpose I/O-pin, it only needs TTL level
voltages. When you flip the switch to make it the Timer1 clock input, now it's a Schmitt
Trigger input.

Check out the BLOCK DIAGRAM OF RA5 to find out why.

It's all right there. Just takes time to learn how to find & decipher it all...;o}

And, when that doesn't work, download the latest Errata sheet for the PIC you're using.
Microchip screws up once in a while, and makes changes to datasheets....;o}

[jellis00]

Bruce, I moved the TMR0 = 0 clear statement after the WRITE statement. However, that is not the problem. I can see while running the code that the TMR0 value is never exceeding the value of K so it never enters the ELSE block and therefore never gets to the WRITE statement which leaves the EEPROM address at inital value of FF continuously.
All this is telling me that my approach to simulating the input pulses by momentarily grounding the RA2 port with my switch closure is not triggering the TMR0 count, but not quite sure what to do about that...I don't yet have access to the meter so I can use real pulse inputs from the sensor.
I understand what you are saying about the threshold value for Vih. However, my 16F690 is running off 5.0 volts, so I would have expected the voltage at RA2 to be near 5.0 volts when the switch is open (not grounded). Yet what I see is 1.8 volts, which is obviously not enough for Vih. This doesn't make sense to me, but explains why the TMR0 value is not incrementing. Any ideas why the RA2 port voltage would be at 1.8 vdc rather than 5.0 vdc when it is unloaded?
I also didn't quite understnd your comments about RA5. My code is a close modification of the Non-interrupt version code you posted above and doesn't even mention RA5 (see current code posting below). Are you saying I have to use RA5 somehow in generating the "clock" input to RA2??

@ __config _INTRC_OSC_NOCLKOUT & _WDT_OFF & _MCLRE_OFF & _CP_OFF
  K CON 15     ' Calibration factor for flow meter = # pulses per gal
  
' Setup Timer0 as an 8-bit counter with the clock input on RA2.
' 1:1 TMR0 prescaler
' TMR0 counts on high-to-low transitions
  OPTION_REG = %00111000
  
' A/D & Comparators disabled
  ANSEL=0           ' all digital
  ANSELH=0          ' analog module disabled
  CM1CON0=0
  CM2CON0=0
  
' Port setup
  PORTC = 0         ' LEDs off, PULSOUT RC3 provides a high-going pulse
  PORTA = 0
  TRISC = %11110000 ' lower 4 pins outputs
  TRISA = %11111111 ' RA2 = 2TMR0 clock input for simulated meter pulse inputs
  TMR0 = 0          ' clear TMR0 count       
  
Main:
  IF TMR0 < K  THEN
    ' Keep the valve open...do nothing..let water flow
    HIGH PORTC.0    ' Light LED continuously while water is flowing
  ELSE
    WRITE 7, TMR0   ' write before TMR0 cleared
    TMR0 = 0        ' clear TMR0 count
    Low PORTC.0     ' Blink LED on each clear after TMR0 >= K
    PAUSE 500
    HIGH PORTC.0    
    PAUSE 500
    LOW PORTC.0
    PULSOUT PORTC.3,1000  ' Generate required 10 msec pulse to RC3 
  ENDIF
  GOTO Main
  END