How to read 4 el.mech.counters? [Archive]

faaktoo

- 6th November 2009, 10:21

Hello !!!
I need help. I want to make a interface that will read impulses from 4 electro mechanical counters at once. The counters operate at different speeds and duration. I have solution for 2 counters, but for 4, hm? Please HELP

DEFINE OSC 8

pinin VAR PORTC.7
pinout VAR PORTC.6

TRISB = 255

B var byte

Serout2 pinout,84,["OK"]

Main:
B = PORTB
pause 10
If PORTB <> 255 then Counter
goto Main

Counter:
B = PORTB
SELECT CASE B

CASE 255
GOTO MAIN
CASE 254
Serout2 pinout,84,["1"] 'counter 1'
GOTO CEK
CASE 253
Serout2 pinout,84,["2"] 'counter 2'
GOTO CEK1
CASE 252
Serout2 pinout,84,["3"] 'counter 1 and counter 2'
GOTO CEK2
END SELECT

GOTO Counter

CEK:
B = PORTB
SELECT CASE B

CASE 255
GOTO MAIN
CASE 253
Serout2 pinout,84,["2"]
GOTO CEK1
CASE 252
Serout2 pinout,84,["2"]
GOTO CEK2
END SELECT

GOTO CEK

CEK1:
B = PORTB
SELECT CASE B

CASE 255
GOTO MAIN
CASE 254
Serout2 pinout,84,["1"]
GOTO CEK
CASE 252
Serout2 pinout,84,["1"]
GOTO CEK2
END SELECT

GOTO CEK1

CEK2:
B = PORTB
SELECT CASE B
CASE 255
GOTO MAIN
CASE 253
GOTO CEK1
CASE 254
GOTO CEK

END SELECT

GOTO CEK2

Darrel Taylor

- 7th November 2009, 02:05

Well, I can't offer any suggestions for fixing what you have, other than CTRL-A/DEL. :)

Give this a try with HyperTerminal or equivalent @ 19200 baud.
I'm assuming it's a 16F877.

CLEAR ' Clear all User RAM
DEFINE OSC 8 ' change to match your crystal
DEFINE LOADER_USED 1 ' if using a bootloader

DEFINE HSER_BAUD 19200 ' Hser baud rate
DEFINE HSER_CLROERR 1 ' Hser clear overflow automatically
DEFINE HSER_RCSTA 90h ' Hser receive status init
DEFINE HSER_TXSTA 24h ' Hser transmit status init

B VAR BYTE
LastB VAR BYTE ' state of pins Last time they changed
Diff VAR BYTE ' Difference tween Last and Current bits
Active VAR BYTE ' Indicates which inputs are active(LOW)
Idx VAR BYTE ' generic loop counter
Counter VAR WORD[4] ' The values of the counters

OPTION_REG.7 = 0 ' enable PORTB pull-ups

;---[clear screen + display menu]-------------------------------------------
Refresh:
HSEROUT [27,"[2J",10,10,10,10,10,10, _
" A=clear All, (1-4)=Clear Counter#, R=Refresh screen"]
GOTO DisplayCounters

Main:
;---[Handle incoming serial data]---------------------------------------
IF PIR1.5 THEN ' If serial data has been received
HSERIN [Idx] ' get the byte
SELECT CASE Idx ' What did we receive?
CASE "A","a" ' A - Clear all counters
FOR Idx = 0 TO 3
Counter(Idx) = 0
NEXT Idx
GOTO DisplayCounters
CASE "R","r" ' Refresh ANSI Terminal screen
GOTO Refresh
CASE "1","2","3","4" ' numbers clear that counter only
Counter(Idx - "1") = 0
GOTO DisplayCounters
CASE ELSE
HSEROUT [8,7] ' send backspace + bell
END SELECT
ENDIF
'---[Count Pulses]------------------------------------------------------
B = PORTB & $F0 ' isolate upper 4-bits
Diff = B ^ LastB ' see if any of them changed
IF Diff != 0 THEN ' if any of them changed
LastB = B
Active = Diff & ~B ' determine which ones are Active
IF Active != 0 THEN
IF Active.4 THEN Counter(0) = Counter(0) + 1 ' increment actives
IF Active.5 THEN Counter(1) = Counter(1) + 1
IF Active.6 THEN Counter(2) = Counter(2) + 1
IF Active.7 THEN Counter(3) = Counter(3) + 1
GOTO DisplayCounters
ENDIF
ENDIF
PAUSE 20
GOTO Main

'--[Display Counter Values]-------------------------------------------------
DisplayCounters:
HSEROUT [27,"[H"] ' home cursor (ANSI)
FOR Idx = 0 TO 3 ' display all counter values
HSEROUT[DEC (Idx+1),": ",DEC5 Counter(Idx),13,10]
NEXT Idx
HSEROUT [13,10]
GOTO Main


Cheers,

Ioannis

- 7th November 2009, 11:29

Nice programming Darrel.

I was just wondering, are really typing all these control characters or is there a trick for this effects?

Ioannis

mackrackit

- 7th November 2009, 11:50

http://www.picbasic.co.uk/forum/showthread.php?t=11794
this is how it is done :)

Ioannis

- 7th November 2009, 12:25

As always there is the obvious in front of us but we try to see further....

Thanks,
Ioannis

Acetronics2

- 8th November 2009, 11:38

;---[clear screen + display menu]-------------------------------------------
Refresh:
HSEROUT [27,"[2J",10,10,10,10,10,10, _
" A=clear All, (1-4)=Clear Counter#, R=Refresh screen"]
GOTO DisplayCounters

Hi, Darrel

Could you explain the second Item in the list: "[2J"

and further

DisplayCounters:
HSEROUT [27,"[H"] ' home cursor (ANSI)

this one : "[H" ???

May be simple for you, but unknown for me !!!

BTW: Thanks for the example ... as I just begin serial comms use to pass parameters to and from my PICs and the PC. ( PC is an horrible black box ... I never look into, as you've understood : LOL )

Alain

Ioannis

- 8th November 2009, 13:30

Alain, this is the ANSI escape codes for the terminals. It does exactly what Darrel remarked, Home position in the terminal window.

Ioannis

Acetronics2

- 8th November 2009, 13:40

Hi, Ioannis

Thanks, but what I do not understand is ... both place cursor @ home position ...

further question will be :

is there any table or link to these codes ??? ...

Alain

Acetronics2

- 8th November 2009, 13:46

Ok Ioannis

With the right words ... Google is my friend !

http://ascii-table.com/ansi-escape-sequences.php

Thanks

Alain

Ioannis

- 8th November 2009, 16:37

Now I got what you meant Alain. But then you caught me on the turn. I was going to post the link for the Escape codes.

I tried them few times, but my terminal was getting confused often. I had to restart it to make it work properly.

Ioannis

faaktoo

- 9th November 2009, 08:57

Man. You are the best! I tried with 16F870 and works perfect.
Now I must write the counters data on internal eprom and send via RS485 to "master" computer on Request. I think I'll be able to in this. For now, thank you very,very much.

PS
I hope you will help me again if it is needed.
It's nice to have your own guru(mentor) :)