Long / short press button...but reading ADC

[fratello]

Hi !
I need again for your help ! I tried to build one simple schematic ; I used 12F675 for reading ADC. Works fine.
But ... I have no clue how to "find" if the button is pressed short (let's say under 1 sec) or long ( > 1 sec) ...for having different commands.
Can someone point me into the right direction ?
Thanks in advance ! Have a nice day and weekend !

@ __config _XT_OSC & _WDT_OFF & _PWRTE_ON & _MCLRE_ON & _BODEN_ON 

DEFINE OSC  4

CMCON    = 7
TRISIO   = %00001001
INTCON   = 0 
IOC      = 0
GPIO     = 0
ANSEL    = %00110001
ADCON0.7 = 1

DataW    var WORD		' Just a WORD Temporary working variable

Main:
ADCON0 = %10000001
	Pauseus 50		' Wait for channel to setup
	ADCON0.1 = 1		' Start conversion
	While ADCON0.1=1:Wend	' Wait for conversion
DataW.HighByte=ADRESH		' Read variable from ADC and save
DataW.LowByte=ADRESL

If DataW > 0 AND DataW < 1023 then GPIO.2 = 1
Pause 1000
GPIO.2 = 0
Goto Main

[Dave]

Fratello, fiest I would change the value of R4 to say... 100 Ohms. That way you are giving the port something less than 1/2 vcc to be seen as a low. Next I would on the trailing edge of the button press, start a loop counter and count some number of time the button is in the down state. When the button is released check the time against a constant of your choosing and see if it longer or shorter than that.

[richard]

don't see this working
won't your adc reading always be > 0 and it can never be higher than 1023

If DataW > 0 AND DataW < 1023 then GPIO.2 = 1

as dave says something like this

@ __config _XT_OSC & _WDT_OFF & _PWRTE_ON & _MCLRE_ON & _BODEN_ON 
DEFINE OSC  4
long_press_threshold con 20   ;2 sec
press_threshold      con 10   ;1 sec
trigger_thresshold   con 600  ; adc reading must fall below this to countr as pressed
CMCON    = 7
TRISIO   = %00001001
INTCON   = 0 
IOC      = 0
GPIO     = 0
ANSEL    = %00110001
ADCON0.7 = 1
DataW    var WORD  ' Just a WORD Temporary working variable
b_cnt    var byte
b_ACT    var byte      ;0 not pressed ,1 pressed for 1 sec ,2 pressed for 2 sec
clear
Main:
    gosub chk_sw
    Pause 100
    if b_ACT then
        if b_ACT ==1 then
           GPIO.2 = 0
        else
            GPIO.2 = 1
        endif
        b_ACT=0
        b_cnt=0
    endif
Goto Main

chk_sw:
ADCON0 = %10000001 ;ch0
Pauseus 50  ' Wait for channel to setup
ADCON0.1 = 1  ' Start conversion
While ADCON0.1=1:Wend ' Wait for conversion
DataW.HighByte=ADRESH  ' Read variable from ADC and save
DataW.LowByte=ADRESL
   if DataW < trigger_thresshold  then
      b_cnt=b_cnt+1   ;if btn is active add to count
      IF  b_cnt > long_press_threshold THEN b_ACT= 2  
   ELSE    ;button released
        if b_cnt > press_threshold THEN   ;press_threshold met
            IF  b_cnt > long_press_threshold THEN
               b_ACT= 2           ;LONG press >2 SEC
            ELSE
               b_ACT= 1
            ENDIF
        ELSE       ;press_threshold not met
        b_ACT= 0
        b_cnt=0    ;reset count
        ENDIF
   endif
return

[fratello]

Thank you both for such fast reply !
Very good info !!! I will test and search for help again if something going wrong...

LE : If DataW > 0 AND DataW < 1023 then GPIO.2 = 1
DataW, with R3=R4=1k, it's "512", don't ?

[richard]

I set the

trigger_thresshold con 600 ; adc reading must fall below this to countr as pressed

to 600 to allow a little safety margin
ooops
note I edited my post to fix timing Pause 100 instead of 50 but I forgot to press the save button till now sorry

[tumbleweed]

I suppose there's some good reason for using the ADC to detect the keypress vs just looking for a digital high/low on the pin?

[richard]

its on a 12f683
the interrupt use is unnecessary , i left it in for experimenting with