Example: How to Use Page Write Feature of I2C EEPROMs [Archive]

sayzer

- 20th May 2008, 11:57

' Omer YILDIZ , Istanbul/TURKEY
' May-2008
' Sayzer @ www.picbasic.co.uk/forum

' This code is to show how to use the page write feature of I2C eeproms.
' Page write feature allows us to write an entire page at one shot,
' and takes one write cycle to complete.
' This code will accept 128-byte packet from RS232 port @9600bps,
' and write the entire packet into 24C512 external eeprom at one shot.
' Incoming 128-bytes packets must have at least 15mS intervals.

' Page size is different from eeprom to eeprom.
' For example: Page size for 24C512 is 128 bytes while
' it is 32 bytes for 24LC64.
' That means, we can write 128-bytes into the eeprom
' at once and it takes only approx 5 - 10 ms.
' If we had to do this one byte at a time, we would have to wait
' approx. 1 second to complete.
' 1 second may not sound that long but,
' think about 64,000 byte waiting to be written !!

' PIC18F452
' Set your fuse settings up here.
DEFINE OSC 20

'Thanks to DT
INCLUDE "DT_INTS-18.bas" ' Base Interrupt System
INCLUDE "ReEnterPBP-18.bas" ' Include if using PBP interrupts

'Thanks to Steve.
DEFINE HSER_RCSTA 90h ' Enable serial port & continuous receive
DEFINE HSER_TXSTA 24h ' Enable transmit, BRGH = 1
DEFINE HSER_SPBRG 129 ' 9600 Baud @ 0,16%
DEFINE HSER_CLROERR 1 ' Clear overflow automatically

'Thanks to MicroChip.
ADCON1 = 7
TrisA = %000000
TrisB = %00000000
TrisC = %10000000 'RC7 => RS232 RX (input pin).
TrisD = %00000000
TrisE = %000

PortA = 0
PortB = 0
PortC = 0
PortD = 0
PortE = 0

I2C_SCL VAR PortC.3
I2C_SDA VAR PortC.4

AdrW VAR WORD ' Address variable for write operation.
AdrR VAR WORD ' Address variable for read operation.

Mem VAR BYTE[1350] ' Create an array as large as possible.
RXFlag VAR BIT ' Just a flag.

Writetime CON 15 ' This is the write cycle time for external eeprom. (mS)
PageSize CON 128 ' Page size for 24C512 : 128 bytes; for 24LC64 : 32 bytes.

'====This is DT's famous and useful Int routine. =========
ASM
INT_LIST macro ; IntSource, Label, Type, ResetFlag?
INT_Handler RX_INT, _ReadPort, PBP, yes
endm
INT_CREATE ; Creates the interrupt processor
ENDASM

@ INT_ENABLE RX_INT ; Enable RX232 RX interrupt

Begin: ' Initial adr values are zero.
RXFlag = 0
AdrW = 0
AdrR = 0

Start:

I2CREAD I2C_SDA, I2C_SCL,$A1,AdrR, [STR Mem\PageSize]
' Read one page from EEPROM and store into mem array.
AdrR = AdrR + PageSize 'First page: 0-127
'Second page: 0 +128 = 128 (128 - 255)
'Third page: 128 +128 = 256 (256 - 383)
'....etc..
' Do your stuff ....

GOTO Start

ReadPort:
HSERIN [STR Mem\PageSize]
' Store 128-byte (0-127) incoming packet into Mem array.

I2CWRITE I2C_SDA, I2C_SCL,$A0,AdrW,[STR Mem\PageSize]
' Starting from addresss location = Adr,
' ...write 128-byte mem elements into EEPROM at one shot.
'...Adr is the start address of the page in line.

PAUSE Writetime ' For 24C512, 15ms is more then good enough.
' For LC series, 5-6 ms should be ok.
AdrW = AdrW + PageSize
' For the next page write, increment EEPROM address
' ...with the size of one page.

RXFlag = 1 ' Set a flag for use in main loop.

@ INT_RETURN

Archangel

- 28th May 2008, 21:37

Thanks Sayzer,
I will try this out.
JS

Ioannis

- 29th May 2008, 08:57

Hi Sayzer.

As the PBP manual states, the control byte must have bit 0 cleared. Is there any special reason that you have made it 1 in this command?

I2CREAD I2C_SDA, I2C_SCL,$A1,AdrR, [STR Mem\PageSize]

But here you still have it cleared:

I2CWRITE I2C_SDA, I2C_SCL,$A0,AdrW,[STR Mem\PageSize]

Regards,
Ioannis

sayzer

- 29th May 2008, 09:23

Hi Sayzer.

As the PBP manual states, the control byte must have bit 0 cleared. Is there any special reason that you have made it 1 in this command?

I2CREAD I2C_SDA, I2C_SCL,$A1,AdrR, [STR Mem\PageSize]

But here you still have it cleared:

I2CWRITE I2C_SDA, I2C_SCL,$A0,AdrW,[STR Mem\PageSize]

Regards,
Ioannis

Hi Ioannis,

The way I read the data sheet of 24C512 eeprom, the write bit is 0 and the read bit is 1.
Same as 24LC64, 24LC512 also.

I agree that it is confusing, but it is a fact that for read operation either 0 or 1 works anyway.

Ioannis

- 29th May 2008, 10:14

Yes, the data sheet clearly states that bit 0 defines read or write. But PBP manual on I2C commands, says that this bit must be kept at 0. May be the compiler takes care of it. Anyway, I am sure it works just fine.

Ioannis

mister_e

- 29th May 2008, 18:03

PBP handle the R/W bit for you.