Searching and Matching Input String with data stored in external EEPROM. [Archive]

sayzer

- 16th December 2009, 09:24

This code is to search a string inside a data stored in an external EEPROM.

For example, an external eeprom is full of IDs in mini packet sizes say 8-byte;
And we have an ID coming from somewhere, serial comm, button etc. and we put that ID in a mini array.
Then, we search the entire external eeprom and try to match the ID with the stored IDs in external EEPROM.

When ID is found, the search is terminated immediately.

Any comments, additions, modifications are welcome.

SDA VAR PORTA.6
SCL VAR PORTA.7
Index1 VAR BYTE BANK0 SYSTEM
Index2 VAR BYTE
IDFound VAR BYTE
EEAdrs VAR WORD

IDSize CON 8 ' The number of the elements of which our StringID is made.
EECap CON 8192 ' IF using 24LC64 for example, eeprom capacity is 8192 bytes.
EEPage CON 32 ' EEprom Page size. For 24LC64, Page size is 32-byte.
ArraySize CON 64 ' Array size.
TempPage VAR BYTE[ArraySize] ' Create Array to store EEProm data.
StringID VAR BYTE[IDSize] BANK0 SYSTEM 'Create Array to store ID string data.

PAUSE 100

Begin:
ARRAYWRITE StringID,["ABCD1234"] ' This is the ID (String) that we will search in external EEPROM.

Menu:

LCDOUT $fe,1, "ID:",STR StringID\IDSize ' Print ID to be searched.
PAUSE 500

GOSUB SearchID ' Search the input string on external EEPROM.

GOTO Begin

SearchID:
EEAdrs = 0 ' Starting location address on external eeprom.

Cont0:
I2CREAD SDA, SCL,$A0,EEAdrs,[STR TempPage\ArraySize] ' Read 64 bytes (ArraySize) at once.

FOR Index2 = 0 TO (ArraySize-1) STEP IDSize ' Search through 64-byte array with IDSize-byte mini packs.

IDFound = 0 ' If ID is found, this variable will be 8.
FOR Index1 = 0 TO (IDSize-1) ' Compare all StringID elements to mini packets inside ArraySize-byte main array.
IF StringID[Index1] = TempPage[Index1+Index2] THEN IDFound = IDFound + 1 ' IF the bytes are the same, increment IDFound.
NEXT Index1

IF IDFound = IDSize THEN Found ' All eight StringID array elements are found & matched in the main array. Exit both "for loops".

NEXT Index2

IF EEAdr >= EECap THEN NotFound ' Searching external EEprom is done. We are now at the last location of external Eprom.
EEAdrs = EEAdrs + ArraySize ' Increment EEprom location address by array size.

GOTO Cont0 ' Search is still in progress, ID not found yet. Keep searching.

NotFound:
LCDOUT $fe,1, "ID Not Found"
PAUSE 500
' Take some action here.

RETURN

Found:
LCDOUT $fe,1, "ID Found"
PAUSE 500
' Take some action here.

RETURN

END